/* 	
*	Petri Leskinen
*	leskinen[dot]petri[at]luukku[dot]com
*  	Espoo, Finland
*	12.3 2008
*/

 package
{
	
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.BlendMode;
	import flash.display.Sprite;
	import flash.display.Stage;
	import flash.display.GradientType;
	
	import flash.events.*;
	import flash.filters.ColorMatrixFilter;
	import flash.filters.ConvolutionFilter;

	import flash.geom.ColorTransform;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;

	import flash.text.TextField;
	import flash.text.TextFormat;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFieldType;	
	
	import flash.ui.Mouse;

public class BubblerGroup extends Sprite
	{
	
	private var bubbles:Array;
	
	// private var inputBox:TextField = new TextField();
	public var txt3D:String = "Text";
	private var txtFields:Array;
	
	function BubblerGroup () {
		
		cacheAsBitmap = true;

		bubbles= new Array();
		var i:int=0;
		var diameter:Number;
		
		for (i=0; i<50; i++) {
			// added 'bubbles' to the scene
			diameter = (i == 0) ? 62.0 : Math.random()*40.0+30.0;
			bubbles[i]= new Bubble(diameter);
			addChild(bubbles[i]);
			
			// choosing a random position on the scene
			bubbles[i].place(Math.random()*250+50, Math.random()*250+70);
			
			// colorTransform gives the 3D- effect of being closer or deeper
			bubbles[i].transform.colorTransform= new ColorTransform(0.0, 0.0, diameter/70.0, 1.0);
			
			// bubbles[0]'s the one that follows the mouse
			if (i != 0) bubbles[i].activate();
		}
		
		// Showing the effect also on a text element !
		generateText( txt3D );
		
		//	ColorMatrixFilter copies the colors from blue-channel adding some tone 
		var colm:ColorMatrixFilter = new ColorMatrixFilter([ 
									0,		0,		-1,	0,		150,
									0,		0,		1.5,	0,		-128,
									0,		0,		1.5,	0,		-128,
									0,		0,		8,		0,		-64	] );//	alpha value for softening the edges 
																			//	blue = 0x08 -> alpha 8*8-64 =0
								
		// Convolution adds the relief-effect
		var conv:ConvolutionFilter = new ConvolutionFilter(	3.0,3.0,
							[ 	0, 	-0.5, 	1,
								-0.5, 	-15, 5,	//	don't even ask how I came up with these values, ... by trying !
								1, 	4,	6 	], 
								1.0);
		
		
		filters =  [ colm , conv ];	 
		
		stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoved); 
		
	}
	
	
	private function generateText(txt3D:String):void {
		
		var size3D:Number = 12.0;
		
		var format:TextFormat = new TextFormat();
			format.font = "Garamond"; // forgot to embed that !
			format.color = 0xFF0000FF;
			format.size = 70;
		
		txtFields= new Array();
		var i:int=0;
		
		for (i=0; i<size3D; i++) {
			txtFields[i] = new TextField();
			addChild(txtFields[i]);
			
			with (txtFields[i]) {
				autoSize =TextFieldAutoSize.LEFT;
				defaultTextFormat = format;
				text= txt3D;
				selectable = false;
				
				x = 100; 
				y = 360 +size3D-i;
				blendMode = BlendMode.LIGHTEN;
				transform.colorTransform  = new ColorTransform( 0,0, Math.sqrt(i/size3D), 1);
			}
		}
		
		// last one on the array of txtfields is set to input ...
		i--;
		txtFields[i].textColor= 0x00000000; 
		txtFields[i].selectable = true;
		txtFields[i].blendMode = BlendMode.ADD;
		txtFields[i].type = TextFieldType.INPUT;
		txtFields[i].addEventListener(TextEvent.TEXT_INPUT, textInputCapture);
	}
	
	// text is editable !
	private function textInputCapture(e:TextEvent):void {
		txt3D = e.target.text;
		for (var i:int=0; i<txtFields.length-1; i++) {
			txtFields[i].text= e.target.text + e.text; // txt3D;
		}
	}
	
	// new cursor following the mouse
	private function mouseMoved(e:MouseEvent):void {
			bubbles[0].x = mouseX;
			bubbles[0].y = mouseY;
			Mouse.hide();
	}
	
	}
}

import flash.display.BlendMode;
import flash.display.Sprite;
import flash.display.Stage;
import flash.display.GradientType;

import flash.events.Event;
import flash.events.MouseEvent;

import flash.geom.Matrix;
import flash.geom.Point;


class Bubble extends Sprite {
	
	public var radius:Number;
	
	// from animating I added these values as original point for this sprite
	private var _xorig:Number =0.0;
	private var _yorig:Number =0.0;
	
	public function Bubble(diameter:Number) {
		
		radius = diameter/2.0;
		
		var gradientBox:Matrix= new Matrix();
		gradientBox.createGradientBox(diameter,diameter, 0, -radius, -radius);
		
		var nr:int = 16;
		var colors:Array = new Array(nr);
		var alphas:Array = new Array(nr);
		var ratios:Array = new Array(nr);
		
		nr--;
		
		for (var i:int =0; i<colors.length; i++) {
			
			// Array ratios gets values from 0 to 0xFF
			ratios[i] = 0xFF*i/nr;
			
			// colors[i] are counted as z-coordinates inside a sphere with radius of 255 units ! 
			// values between 0...255, I've only used the blue channel so far !
			colors[i] = Math.sqrt(65025.0-ratios[i]*ratios[i]);
			
			alphas[i] = 1;
		}
		
		//	one 'Bubble' is just a circular gradientFill with color value 0xFF at center and 0x00 on the edges
		this.graphics.beginGradientFill(GradientType.RADIAL,
				colors,
				alphas,
				ratios,
				gradientBox);
		this.graphics.drawCircle(0,0,radius);
		this.graphics.endFill();
		
		this.blendMode = BlendMode.LIGHTEN;
		
	}
	
	public function place(_x:Number, _y:Number):void {
		x = _xorig = _x;
		y = _yorig = _y;
	}
	
	public function activate():void {
		addEventListener(Event.ENTER_FRAME, mouseMoved);
	}
	
	private function mouseMoved(e:Event):void {
		var po:Point = new Point(mouseX,mouseY);
		
		// mouse interaction
		// new position and scaling is counted by the distance to the mouse
		po.x /= radius;
		po.y /= radius;
		var dst2:Number = 1.0/(1.0+Math.abs(po.x)+Math.abs(po.y) );
		
		scaleX = (3.0*scaleX + 1.0-dst2)*0.25;
		scaleY = (3.0*scaleY + 1.0-dst2)*0.25;
		
		dst2 *= radius;
		x = int(3*x+ _xorig + dst2*po.x) >>2;
		y = int(7*y+ _yorig + dst2*po.y) >>3;
		
	}
}