// 	Petri Leskinen, leskinen[dot]petri[at]luukku.com
//	July 2008,  Espoo, Finland

package {
	import flash.display.Sprite;
	import flash.display.BitmapData;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.display.GraphicsPathCommand;
	import flash.events.Event;
	import flash.events.MouseEvent ;
	
	public class GraphicsRadial2 extends Sprite {
		
		public var color:uint = 0x00;
		public var n:int =48; // curve length
		
		public var perlinData:BitmapData;
		public var po:Array= [ new Point(),
						new Point(),
						new Point() ];
		
		public var paused:Boolean = false;
		
		private var _commands:Vector.<int> = new Vector.<int>();
		private var _dataUint:Vector.<uint>;
		private	var _dataVector:Vector.<Number>;
		private var  angles:Array;
		private var i:int;
		
		public function GraphicsRadial2(_color:uint = 0x00) {
			this.color = _color;
			
			// init the vector '_commands' :
			// first command MOVE_TO, all other CURVE_TO
			_commands.push(GraphicsPathCommand.MOVE_TO);
			for (i=0 ; i<n; i+=2) {
				_commands.push(GraphicsPathCommand.CURVE_TO,
							   GraphicsPathCommand.CURVE_TO,
							   GraphicsPathCommand.CURVE_TO,
							   GraphicsPathCommand.CURVE_TO,
							   GraphicsPathCommand.CURVE_TO,
							   GraphicsPathCommand.CURVE_TO
							   );
			}
			
			var angle:Number = 360.0/n *Math.PI/180.0;
			var sina:Number = Math.sin(angle);
			var cosa:Number = Math.cos(angle);
			
			// init precounted cosines and sines for angles, 
			var rot:Array = [1.0,0.0];
			angles = new Array(n);
			for (i=0; i!=n; i++) {
				angles[i] = { cos:rot[0], sin:rot[1] };
				rot = [ cosa*rot[0]-sina*rot[1],sina*rot[0]+cosa*rot[1] ];
			}
			
			perlinData = new BitmapData(n,8,false);
			 
			upDate(new Event(Event.RENDER));
			addEventListener(Event.ENTER_FRAME, upDate);
			addEventListener(MouseEvent.CLICK, mouseClicked);
		}
		
		
		private function upDate(e:Event):void {
			// animate perlinNoise
			po[0].x += 1.0;
			po[0].y += 0.03;
			po[1].x += 0.30;
			po[1].y += 0.01;
			po[2].x += 0.012510;
			perlinData.perlinNoise(0.5*n,8,2,13,
							   true,true,4,true, po);
					
			_dataVector = new Vector.<Number>();
								
			var r0:int = perlinData.getPixel(0,0)&0xFF;
			pxlToCurve(0,1);
			
			for (i=0; i<n; i +=2) {
				//	coordinates in pairs,
				//	controls point,
				//	curve point ...
				pxlToCurve(i,0); 
				pxlToCurve(i+1,0); 
				pxlToCurve(i+2,0);
				pxlToCurve(i+2,1); 
				pxlToCurve(i+2,2); 
				pxlToCurve(i+1,2); 
				
				pxlToCurve(i,2); 
				pxlToCurve(i,3); 
				pxlToCurve(i,4); 
				pxlToCurve(i+1,4); 
				pxlToCurve(i+2,4); 
				pxlToCurve(i+2,1); 
				
			}
			
			with (this.graphics) {
				clear();
				beginFill(color,1.0);
				lineStyle(0.5,0xFFFFFF, 1.0);
				
				drawPath(_commands, _dataVector);
				endFill();
			}
		}
		
		private function pxlToCurve(x:int, y:int):void {
			//	convert x,y-coordinate defined by
			//	pixel data to polar coordinates
			
			var x0:int = x%n;
			var div:int =3; // controls the pattern size
			
			var r:int = perlinData.getPixel(x0,0)&0xFF ;
			
			if (y>0) {
				r += perlinData.getPixel(x0,1)&0xFF;
				if (y>1) {
					r += perlinData.getPixel(x0,2)&0xFF;
					if (y>2) r += perlinData.getPixel(x0,3)&0xFF;
					if (y>3) r += perlinData.getPixel(x0,4)&0xFF;
					if (y>4) r += perlinData.getPixel(x0,5)&0xFF;
				}
			}
			
			r = 12+ (r>>div); // 12 - center radius
			
			_dataVector.push( r*angles[x0].cos,r*angles[x0].sin );
		}
		
		// mouse click pauses motion
		private function mouseClicked(e:MouseEvent):void {
			if (paused) {
				addEventListener(Event.ENTER_FRAME, upDate);
			} else {
				removeEventListener(Event.ENTER_FRAME, upDate);
			}
			paused = !paused;
		}
		
	}
}